mirror of
https://github.com/curl/curl.git
synced 2026-04-11 12:01:42 +08:00
89043ba906
Require CMake 3.18 (2020-07-15) or newer, up from 3.7 (2016-11-11) prior to this patch. This requirement also applies to the distributed `curl-config.cmake`. To allow dropping compatibility code maintained for old versions, and to use features which were unpractical in separate code paths. Also to make testing, documentation and development easier, CI builds faster due to CMake performance improvements over time. (e.g. integration tests on macOS run 8x faster (10 minutes is now under 1.5m) in CI, 2.5x faster on Windows.) CMake offers pre-built binaries for major platforms. They work without an install step, just by unpacking and pointing the cmake command to them. Making upgrades easy in many cases: https://cmake.org/download/ https://cmake.org/files/ https://github.com/Kitware/CMake/releases CMake 3.18 brings these feature as generally available when building or consuming curl/libcurl: LTO support, improved performance, `pkg-config` and interface target support, `OBJECT` target (for faster libcurl builds), modern invocation with `-S`/`-B` options, better support for custom linker options, FetchContent, `GnuTLS::GnuTLS` target, `--verbose` and `--install` options, `CMAKE_GENERATOR` env, last but not least unity mode and Ninja generator. For maximum build speed, use: `-DCMAKE_UNITY_BUILD=ON -DCURL_DROP_UNUSED=ON` As for deprecations, C++11 is required to build CMake itself, which may be a limit on some platforms. autotools continues to cover them. Follow-up to9bcdfb3809#20408 Follow-up toa7c974e038#19902 Follow-up todfbe035c8b#10161 Discussion: https://github.com/curl/curl/discussions/18704 Closes #20407
93 lines
3.2 KiB
CMake
93 lines
3.2 KiB
CMake
#***************************************************************************
|
|
# _ _ ____ _
|
|
# Project ___| | | | _ \| |
|
|
# / __| | | | |_) | |
|
|
# | (__| |_| | _ <| |___
|
|
# \___|\___/|_| \_\_____|
|
|
#
|
|
# Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al.
|
|
#
|
|
# This software is licensed as described in the file COPYING, which
|
|
# you should have received as part of this distribution. The terms
|
|
# are also available at https://curl.se/docs/copyright.html.
|
|
#
|
|
# You may opt to use, copy, modify, merge, publish, distribute and/or sell
|
|
# copies of the Software, and permit persons to whom the Software is
|
|
# furnished to do so, under the terms of the COPYING file.
|
|
#
|
|
# This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY
|
|
# KIND, either express or implied.
|
|
#
|
|
# SPDX-License-Identifier: curl
|
|
#
|
|
###########################################################################
|
|
# Find the GnuTLS library
|
|
#
|
|
# Input variables:
|
|
#
|
|
# - `GNUTLS_INCLUDE_DIR`: Absolute path to GnuTLS include directory.
|
|
# - `GNUTLS_LIBRARY`: Absolute path to `gnutls` library.
|
|
#
|
|
# Defines:
|
|
#
|
|
# - `GNUTLS_FOUND`: System has GnuTLS.
|
|
# - `GNUTLS_VERSION`: Version of GnuTLS.
|
|
# - `CURL::gnutls`: GnuTLS library target.
|
|
|
|
set(_gnutls_pc_requires "gnutls")
|
|
|
|
if(CURL_USE_PKGCONFIG AND
|
|
NOT DEFINED GNUTLS_INCLUDE_DIR AND
|
|
NOT DEFINED GNUTLS_LIBRARY)
|
|
find_package(PkgConfig QUIET)
|
|
pkg_check_modules(_gnutls ${_gnutls_pc_requires})
|
|
endif()
|
|
|
|
if(_gnutls_FOUND)
|
|
set(GnuTLS_FOUND TRUE)
|
|
set(GNUTLS_FOUND TRUE)
|
|
set(GNUTLS_VERSION ${_gnutls_VERSION})
|
|
message(STATUS "Found GnuTLS (via pkg-config): ${_gnutls_INCLUDE_DIRS} (found version \"${GNUTLS_VERSION}\")")
|
|
else()
|
|
find_path(GNUTLS_INCLUDE_DIR NAMES "gnutls/gnutls.h")
|
|
find_library(GNUTLS_LIBRARY NAMES "gnutls" "libgnutls")
|
|
|
|
unset(GNUTLS_VERSION CACHE)
|
|
if(GNUTLS_INCLUDE_DIR AND EXISTS "${GNUTLS_INCLUDE_DIR}/gnutls/gnutls.h")
|
|
set(_version_regex "#[\t ]*define[\t ]+GNUTLS_VERSION[\t ]+\"([^\"]*)\"")
|
|
file(STRINGS "${GNUTLS_INCLUDE_DIR}/gnutls/gnutls.h" _version_str REGEX "${_version_regex}")
|
|
string(REGEX REPLACE "${_version_regex}" "\\1" _version_str "${_version_str}")
|
|
set(GNUTLS_VERSION "${_version_str}")
|
|
unset(_version_regex)
|
|
unset(_version_str)
|
|
endif()
|
|
|
|
include(FindPackageHandleStandardArgs)
|
|
find_package_handle_standard_args(GnuTLS
|
|
REQUIRED_VARS
|
|
GNUTLS_INCLUDE_DIR
|
|
GNUTLS_LIBRARY
|
|
VERSION_VAR
|
|
GNUTLS_VERSION
|
|
)
|
|
|
|
if(GNUTLS_FOUND)
|
|
set(_gnutls_INCLUDE_DIRS ${GNUTLS_INCLUDE_DIR})
|
|
set(_gnutls_LIBRARIES ${GNUTLS_LIBRARY})
|
|
endif()
|
|
|
|
mark_as_advanced(GNUTLS_INCLUDE_DIR GNUTLS_LIBRARY)
|
|
endif()
|
|
|
|
if(GNUTLS_FOUND)
|
|
if(NOT TARGET CURL::gnutls)
|
|
add_library(CURL::gnutls INTERFACE IMPORTED)
|
|
set_target_properties(CURL::gnutls PROPERTIES
|
|
INTERFACE_LIBCURL_PC_MODULES "${_gnutls_pc_requires}"
|
|
INTERFACE_COMPILE_OPTIONS "${_gnutls_CFLAGS}"
|
|
INTERFACE_INCLUDE_DIRECTORIES "${_gnutls_INCLUDE_DIRS}"
|
|
INTERFACE_LINK_DIRECTORIES "${_gnutls_LIBRARY_DIRS}"
|
|
INTERFACE_LINK_LIBRARIES "${_gnutls_LIBRARIES}")
|
|
endif()
|
|
endif()
|